Results 1 to 2 of 2
  1.    #1  
    I just got my Treo 750 a couple days ago, but i've already discovered how great of a tool MortScript can be! I found hannip's script to turn on LED notifications for missed calls, but I was looking for an LED notification for everything EXCEPT email, since I use multiple accounts and get a lot of unimportant email. So I edited the script to flash the LED for all notifications except for email, and here it is. I thought I would go ahead and post it in case there was somebody out there that was in the same boat.

    I haven't tested this script to great lengths, but so far it seems to work great on my 750.

    hannip, I hope you don't mind if I edited your script.

    Code:
    #
    # NLED.mscr - Monitors notifications and turns on and off the notification LED
    # for all notifications EXCEPT email
    #
    
    # check dependencies
    If ( NOT FileExists( "\Windows\LEDUp.exe" ) )
       Message ( "Installation of LEDUp.exe is required! Exiting...", "NLED script" )
       Exit
    EndIf
    
    # initialize variables
    LedOn = FALSE
    Notify = FALSE
    EmailID = "{A877D65A-239C-47A7-9304-0D347F580408}"
    
    # start notification check loop
    While ( 1 )
    
    # check the registry for any notifications
       If ( RegValueExists( "HKLM", "System\State\Shell\Notifications\Active", "CLSID" ) )
    
    # make sure it's not an email
    
          CLSID = RegRead( "HKLM", "System\State\Shell\Notifications\Active", "CLSID" )
    
          If ( CLSID ne EmailID )
             Notify = True
          EndIf
       
       Else
          Notify = False
       EndIf
    
    # turn on the led if any notifications are pending. Keep turning on each iteration since
    # the OS turns it off whenever there is a new notification.
    
       If ( Notify )
          RunWait( "\Windows\LEDUp.exe", "0 1" )
          LedOn = TRUE
       EndIf
    
    # turn off the led if no notifications are pending
       If ( LedOn && NOT Notify )
          RunWait( "\Windows\LEDUp.exe", "0 0" )
          LedOn = FALSE
       EndIf
    
    # wait 5 seconds
       Sleep( 5000 )
    
    EndWhile
  2. #2  
    I don't mind at all. Good job kewlair!

    In a future Treo Alerts version we are planning on making each notification type selectable. The one issue I'm running into is that if there are multiple notifications active and some of them are ones you haven't selected you have to dismiss all of them to turn off the alerts. I'm hoping that eVC gives me a bit more control on being able to detect when specific notifications are dismissed to get around that problem.

Posting Permissions